塩分に起因する鉄筋の腐食速度/Calculation of Rate of Corrosion of Reinforcing Steel caused by Chlorid in Concrete By MORINAGA Formula.

Equation
q_{2}=\frac{d}{c^{2}}\{-0.51-7.60N+44.97(w/c)^{2}+67.95N(w/c)^{2}\}

q_{3}=2.59-0.05x_{1}-6.89x_{2}-22.87x_{3}-0.99x_{4}+0.14x_{5}+0.51x_{6}+0.01x_{7}+60.81x_{8}+3.36x_{9}+7.32x_{10}

w/c(%):水セメント比/Water/Cement Weight Ratio.
N(%):練りまぜ水に対する塩分濃度/NaCl Concentration of Mixing Water.
d(mm):鉄筋径/Diameter of Reinforcing Bar.
c(mm):かぶり厚さ/Concrete Cover Depth.
T(℃):温度/Temperature.
RH(%):湿度/Relative Humidity.
O(%):酸素濃度/Concentration of Oxygen.

※詳細は下記参考文献参照。
Scilab
2660126602
2660326604

 -->clear;
-->function q3=func_q3(T,RH,O,N)
-->    x1=T;
-->    x2=(RH-45)/100;
-->    x3=O/100;
-->    x4=N;
-->    x5=x1*x2;
-->    x6=x1*x3;
-->    x7=x1*x4;
-->    x8=x2*x3;
-->    x9=x2*x4;
-->    x10=x3*x4;
-->    q3=2.59-0.05*x1-6.89*x2-22.87*x3-0.99*x4+0.14*x5+0.51*x6+0.01*x7+60.81*x8+3.36*x9+7.32*x10;
-->endfunction
-->function q2=func_q2(d,c,N,wc)
-->    q2=d/c^2*(-0.51-7.6*N+44.97*(wc/100)^2+67.95*N*(wc/100)^2);
-->endfunction
-->function q=func_q()
-->    q=func_q2(d,c,N,wc)*func_q3(T,RH,O,N)/func_q3(15,69,20,N);
-->    if q<0 then
-->        q=0;
-->    end
-->endfunction
-->for www=1:4;
-->    funcprot(0);
-->    equation='q=func_q()';
-->    xset("window",www);clf();xgrid();
-->    graphtitle='Rate of Corrosion of Reinforcing Steel';
-->    wc=65;
-->    N=0.825;
-->    d=9;
-->    c=20;
-->    T=20;
-->    RH=70;
-->    O=20;
-->    n=100;
-->    if www==1 | www==2 then
-->        wc=linspace(40,60,n);
-->        RH=linspace(50,70,n);
-->        xtitle(graphtitle,'wc(%)','RH(%)','Rate(*10^-4・g/cm^2/year)',boxed=1);
-->        fnt='[q]=func1(wc,RH)';
-->        deff(fnt,equation);
-->        if www==1 then 
-->            R=245;
-->            G=255;
-->            B=250;
-->            color(R,G,B);
-->            idcolor=color(R,G,B);
-->            fplot3d(wc,RH,func1,flag=[idcolor , 2 , 4]);
-->        elseif www==2 then
-->            nz=30;
-->            contour(wc,RH,func1,nz,flag=[2,2,4]);
-->            ax=gca();
-->            for iii=1:nz;
-->                cnt=ax.children(iii).children;
-->                eee=length(cnt);
-->                if eee==2 then
-->                    cnt(2).font_size=4;
-->                end
-->            end
-->            func1(60,70)    
-->        end
-->    else
-->        c=linspace(1,20,n);
-->        T=linspace(20,30,n);
-->        xtitle(graphtitle,'c(mm)','T(℃)','Rate(*10^-4・g/cm^2/year)',boxed=1);
-->        fnt='[q]=func2(c,T)';
-->        deff(fnt,equation);
-->        if www==3 then 
-->            R=216;
-->            G=191;
-->            B=216;
-->            color(R,G,B);
-->            idcolor=color(R,G,B);
-->            fplot3d(c,T,func2,flag=[idcolor , 2 , 4]);
-->        elseif www==4 then
-->            contour(c,T,func2,30,flag=[2,2,4]); 
-->            ax=gca();
-->            for iii=1:nz;
-->                cnt=ax.children(iii).children;
-->                eee=length(cnt);
-->                if eee==2 then
-->                    cnt(2).font_size=4;
-->                end
-->            end
-->            func2(20,30)
-->        end
-->    end 
-->    currentaxes=gca();
-->    currentaxes.font_size=6;
-->    currentaxes.title.font_size=6;
-->    currentaxes.x_label.font_size=6;
-->    currentaxes.y_label.font_size=6;
-->    currentaxes.z_label.font_size=6;
-->    currentaxes.tight_limits="on";
-->    currentaxes.cube_scaling="on";
-->    currentaxes.auto_clear="on";
-->    currentaxes.auto_scale="on";
-->end
 ans  =
 
    0.8861478  
 ans  =
 
    1.5161159  

SciNotes

clear;
function q3=func_q3(T,RH,O,N)
    x1=T;
    x2=(RH-45)/100;
    x3=O/100;
    x4=N;
    x5=x1*x2;
    x6=x1*x3;
    x7=x1*x4;
    x8=x2*x3;
    x9=x2*x4;
    x10=x3*x4;
    q3=2.59-0.05*x1-6.89*x2-22.87*x3-0.99*x4+0.14*x5+0.51*x6+0.01*x7+60.81*x8+3.36*x9+7.32*x10;
endfunction
function q2=func_q2(d,c,N,wc)
    q2=d/c^2*(-0.51-7.6*N+44.97*(wc/100)^2+67.95*N*(wc/100)^2);
endfunction
function q=func_q()
    q=func_q2(d,c,N,wc)*func_q3(T,RH,O,N)/func_q3(15,69,20,N);
    if q<0 then
        q=0;
    end
endfunction
for www=1:4;
    funcprot(0);
    equation='q=func_q()';
    xset("window",www);clf();xgrid();
    graphtitle='Rate of Corrosion of Reinforcing Steel';
    wc=65;
    N=0.825;
    d=9;
    c=20;
    T=20;
    RH=70;
    O=20;
    n=100;
    if www==1 | www==2 then
        wc=linspace(40,60,n);
        RH=linspace(50,70,n);
        xtitle(graphtitle,'wc(%)','RH(%)','Rate(*10^-4・g/cm^2/year)',boxed=1);
        fnt='[q]=func1(wc,RH)';
        deff(fnt,equation);
        if www==1 then 
            R=245;
            G=255;
            B=250;
            color(R,G,B);
            idcolor=color(R,G,B);
            fplot3d(wc,RH,func1,flag=[idcolor , 2 , 4]);
        elseif www==2 then
            nz=30;
            contour(wc,RH,func1,nz,flag=[2,2,4]);
            ax=gca();
            for iii=1:nz;
                cnt=ax.children(iii).children;
                eee=length(cnt);
                if eee==2 then
                    cnt(2).font_size=4;
                end
            end
            func1(60,70)    
        end
    else
        c=linspace(1,20,n);
        T=linspace(20,30,n);
        xtitle(graphtitle,'c(mm)','T(℃)','Rate(*10^-4・g/cm^2/year)',boxed=1);
        fnt='[q]=func2(c,T)';
        deff(fnt,equation);
        if www==3 then 
            R=216;
            G=191;
            B=216;
            color(R,G,B);
            idcolor=color(R,G,B);
            fplot3d(c,T,func2,flag=[idcolor , 2 , 4]);
        elseif www==4 then
            contour(c,T,func2,30,flag=[2,2,4]); 
            ax=gca();
            for iii=1:nz;
                cnt=ax.children(iii).children;
                eee=length(cnt);
                if eee==2 then
                    cnt(2).font_size=4;
                end
            end
            func2(20,30)
        end
    end 
    currentaxes=gca();
    currentaxes.font_size=6;
    currentaxes.title.font_size=6;
    currentaxes.x_label.font_size=6;
    currentaxes.y_label.font_size=6;
    currentaxes.z_label.font_size=6;
    currentaxes.tight_limits="on";
    currentaxes.cube_scaling="on";
    currentaxes.auto_clear="on";
    currentaxes.auto_scale="on";
end

参考文献
森永繁(1986).『鉄筋の腐食速度に基づいた鉄筋コンクリート建築物の寿命予測に関する研究』

Remarks
N=58.44/35.45*Weight of Chlorine-Ion in concrete(kg/m^3)/Unit Water Weight(kg/m^3)*100.
Example:If Weight of Chlorine-ion in concrete(kg/m^3) is 1.0(kg/m^3) and Unit Water Weight is 200(kg/m^3) ,N equals 0.825%.